Удвоение пинов Arduino (1)

Часто приходится слышать, что "буду покупать Arduino Mega, потому что в обычном Arduino мало выводов". Действительно: а что делать, если цифровых выводов Arduino хронически не хватает? Тем, кто настроен на покупку, настоятельно рекомендую Freeduino Mega 2560 - по крайней мере, и выводов, и возможностей у нее побольше.

Но есть и более дешевый способ, о котором не подозревают начинающие. Попытаемся исправить ;)

Часть I. Размножение выходов, или ShifOut

Понадобится логическая микросхема, которая принимает данные последовательно, а выдает – параллельно. Наиболее популярным решением является 74HC595:



Полностью ее название звучит как 8-bit serial-in, serial or parallel-out shift register with output latches; 3-state, а по-русски - восьмибитный сдвиговый регистр с последовательным входом и последовательным или параллельным выходом с защелкой и высокоимпендансным выходом.

Для нас это значит, что микросхема умеет последовательно, бит за битом, принимать данные по двум входам и по команде "покажи" выставлять полученный код на своих восьми выходах. Заглянем внутрь (а там сплошные триггеры ;):



"Защелка" (по англ. latch) – это регистр хранения на выходе, который удерживает предыдущий принятый код, пока последовательным способом принимается очередная порция данных. В процессе сдвига данные передаются слева направо между триггерами FFx: со входа DS в FF0, с выхода FF0 в FF1 и так далее; самое последнее значение "выталкивается" из FF7 и теряется навсегда в окружающем пространстве-времени. Но расстраиваться не стоит - это же сдвиговый регистр, ему так и положено работать! ;) В нужный момент FFx переписываются "вниз" - в триггеры LATCH и, если на то будет инверсный разрешающий сигнал OE (Output Enable), код появится на выходах Q0-Q7.

Eagle в курсе про 74HC595, искомый элемент располагается в библиотеке "74xx-eu", секция "74*595". Рисуем простейшую схему:

Немного смущает различное наименование выводов чипа 74HC595 в datasheet и в Eagle - видимо сказывается длительный срок жизни этой микросхемы. Но в любом случае, смысл у них один и тот же. На схеме сделаны следующие соединения:

• вывод 8 – земля микросхемы 
• вывод 16 – питание микросхемы 
• вывод 13 - инверсное разрешение вывода информации – уровень логического нуля на этом входе разрешает выставить хранимый в защелке код на параллельные выходы (Q0-Q7, они же QA-QH). Для простоты подключаем к GND - всегда выводить;
• вывод 10 – инверсный вход сброса сдвигового регистра. Тоже обходимся без него, поэтому делаем его пожизненно неактивным -  подаем туда логическую единицу (на то он инверсный), притягивая к питанию VСС;
• вывод 14 - последовательный вход данных от МК. Подключаем его к digital 11;
• вывод 11 - вход синхронизации данных, подключаем к digital 12;
• вывод 12 - синхронизация защелки, подключаем к digital 8.

Как видите, в самом простом варианте у Arduino расходуются только три цифровых выхода.

#define DS   11
#define SHCP 12
#define STCP 8

void send595(byte output) {
  for (int i=0;i<8;i++){
    digitalWrite(DS,output & 1);
    digitalWrite(SHCP,LOW);
    delay(1);
    digitalWrite(SHCP,HIGH);
    output >>= 1;
  }
  digitalWrite(STCP,HIGH);
  delay(1);
  digitalWrite(STCP,LOW);  
}

void setup() {
  pinMode(DS,OUTPUT);
  pinMode(SHCP,OUTPUT);
  pinMode(STCP,OUTPUT);
  digitalWrite(SHCP,LOW);  
  digitalWrite(STCP,LOW);  
}

void loop() {
  for (int k=0;k<256;k++) {
    send595(k);
    delay(100);
  }
}

Если к каждому из выходов SV2 подключить по светодиоду, то мы сможем визуально последовательно наблюдать, как выглядят двоичные числа от 0 до 255 (снова и снова, пока работает loop ;).

Данные передаются по линии DS, при этом микросхема 595 воспринимает их по фронту сигнала SH_CP - это такой момент времени, когда сигнал переходит из состояния логического нуля в единицу. По окончании приема очередных восьми бит надо ненадолго установить ST_CP, чтобы поместить данные в защелку.

Я поместил вывод байта в отдельную процедуру send595(output) для наглядности, но теперь пора открыть страшную тайну пояснить, что в языке Wiring предусмотрен специальный оператор shiftOut(dataPin, clockPin, bitOrder, value), выполняющий побитовый вывод байтового значения value в порядке bitOrder (имеется ввиду направление вывода value - от старшего бита к младшему или наоборот - от младшего к старшему) через dataPin и clockPin. Как раз подходит для нашего случая:

#define DS   11
#define SHCP 12
#define STCP 8

void setup() {
  pinMode(DS,OUTPUT);
  pinMode(SHCP,OUTPUT);
  pinMode(STCP,OUTPUT);
  digitalWrite(SHCP,LOW);  
  digitalWrite(STCP,LOW);  
}

void loop() {
  for (int k=0;k<256;k++) {
    shiftOut(DS,SHCP,LSBFIRST,k);
    digitalWrite(STCP,HIGH);
    delay(1);
    digitalWrite(STCP,LOW); 
    delay(100);
  }
}

Подведем промежуточные итоги.

Мы пожертвовали тремя,  получили 8, в итоге добавив 5 дополнительных входов. У обычного Arduino 19 выходов, и, теоретически, можно использовать 6 групп по 3, получив 6 * 8 = 48 выходов.

Но не спешите делать вывод, что это предел. Предела вообще нет! Благодаря специальному последовательному выходу Q7`, можно объединить несколько микросхем, получив 16, 24, 32 и т. д. разрядов:

Теперь о грустном.  Конечно, наращивать число ножек до бесконечности не получится. Препятствовать этому будут требования к максимальной частоте изменения сигнала на выходе.

Чтобы изменить состояние хотя бы даже одного из выходов 75HC595, нам придется прогнать  последовательно все 8, 16, 24, 32... разряда через вход DS. Чем больше разрядов - тем больше время установки. А чем больше времени тратится на изменение одного разряда, тем меньше скорость изменения выходного сигнала. Впрочем, вполне вероятно, для некоторых приложений это ограничение не будет существенным, попробуем подсчитать.

На вывод одного разряда необходимо как минимум выполнить одну ассемблерную инструкцию сдвига, одну - вывода в порт и две - на переход в цикле. МК построен по RISC-архитектуре и выполняет одну операцию за такт, работая на частоте 16 МГц. Значит, четыре такта он обрабатывает за 250 нс. Таким образом байт будет выведен не менее, чем за 2 мкс, а предельная частота составит 0,5 МГц (это грубая прикидка верхнего значения -  буду признателен, если кто-то подсчитает точнее).

Побороться с этим пределом будет довольно сложно, потому что все известные мне пути довольно ограничены:

• повысить тактовую частоту МК больше 16 МГц: потеряем базовую совместимость с Arduino, придется исправлять константу в библиотеке, менять кварц на плате. Больше 20 МГц не получится, увы - а это прирост всего-то на 25%;
• повысить питание 75HC595N: таково уж свойство КМОП-логики - чем больше напряжение, тем быстрее работает. Но МК Arduino (тоже построенный на КМОП) и так работает на предельном напряжении 4,5..5,5В, и вот его-то ускорить уже не удастся;  В то же время, быстродействие зависит и от серии микросхемы - можно по крайней мере не выбирать древние и медленные. Ставьте современные 74HC595 или даже 74HCT595 и будете иметь в запасе предел 100 МГц, который с запасом "накрывает" способности нашего МК в Arduino.

Таким образом, с выходами разобрались.

А что нужно делать, чтобы размножить входы? Читайте во второй части.

(использованы материалы из статьи Serial to Parallel Shifting-Out with a 74HC595)